www.neuron.yale.edu

Code: Select all

NEURON {
  POINT_PROCESS Psyn
  USEION ps READ psi WRITE psi VALENCE 1
  NONSPECIFIC_CURRENT i
  RANGE taug, taups, e, i
}

PARAMETER {
  : change these to whatever you need
  e = 0 (mV)
  g0 = 1e-4 (uS) : or whatever it should start at
  taug = 3 (ms) : decay of synaptic conductance
  taups = 25 : decay of potentiating substance
  k = 0.5 : how strongly ica affects the potentiating substance
  kpsi = 1 (/mM) : effect of psi on synaptic strength
  psi0 = 0 (mM) : initial concentration of psi
}

ASSIGNED {
  v (mV)
  i (nA)
}

STATE {
  g (uS)
  psi (mM) : intracellular concentration of the potentiating substance
}

INITIAL {
  g = 0
  psi = psi0
}

BREAKPOINT {
  SOLVE state METHOD cnexp
  i = g*(v - e)
}

DERIVATIVE state {
  g' = -g/taug
  psi' = -(k*i + psi)/taups
}

NET_RECEIVE (weight (uS)) {
  g = g+weight*(1 + kpsi*psi)
}

Code: Select all

NEURON {
  POINT_PROCESS Psyn
  NONSPECIFIC_CURRENT i
  RANGE taug, taups, e, i
}
 . . .
PARAMETER {
 . . .
  taups = 25  (ms) : decay of potentiating substance
  : this value for k may be much too big
  k = 0.5 (mM/nA) : how strongly i affects the potentiating substance
  kps = 1 (/mM) : effect of ps on synaptic strength
  ps0 = 0 (mM) : initial concentration of psi
}
 . . .
STATE {
  g (uS)
  ps (mM) : intracellular concentration of the potentiating substance
}

INITIAL {
  g = 0
  ps = ps0
}
 . . .
DERIVATIVE state {
  g' = -g/taug
  ps' = -(k*i + ps)/taups
}

NET_RECEIVE (weight (uS)) {
  g = g+weight*(1 + kps*ps)
}

Code: Select all

COMMENT
A synaptic mechanism with use-dependent plasticity that is 
governed by the current that flows through the synapse.

Caveats:
1.  Does not have stream-specific plasticity, so each instance 
should be driven by only 1 NetCon.  However, the "potentiating stuff" 
variable ps is treated as an ordinary STATE, not an ion, so that 
multiple synaptic mechanisms of the same type can be attached to 
the same compartment.

2.  Potential bug:  nothing in this code prevents ps from becoming 
negative.  If ps < 0, g itself could become negative.  This model 
should really be reformulated to prevent ps from falling below 0, 
or at least to prevent g from becoming negative, and it should be 
done in a mechanistically plausible way.
ENDCOMMENT

NEURON {
  POINT_PROCESS Psyn
  NONSPECIFIC_CURRENT i
  RANGE taug, taups, e, i
}

UNITS {
  (mV) = (millivolt)
  (nA) = (nanoamp)
  (uS) = (microsiemens)
  (mM) = (milli/liter)
}

PARAMETER {
  : change these to whatever you need
  e = 0 (mV)
  g0 = 1e-4 (uS) : or whatever it should start at
  taug = 3 (ms) : decay of synaptic conductance
  taups = 25 (ms) : decay of potentiating substance
  ps0 = 0 (mM) : initial concentration of ps
  : this value for k may be much too big
  k = 0.5 (mM/nA) : how strongly ica affects the potentiating substance
  kps = 1 (/mM) : effect of ps on synaptic strength
}

ASSIGNED {
  v (mV)
  i (nA)
}

STATE {
  g (uS)
  ps (mM) : "concentration" of the "potentiating substance"
}

INITIAL {
  g = 0
  ps = ps0
}

BREAKPOINT {
  SOLVE state METHOD cnexp
  i = g*(v - e)
}

DERIVATIVE state {
  g' = -g/taug
  ps' = -(k*i + ps)/taups
}

NET_RECEIVE (weight (uS)) {
  g = g + weight*(1 + kps*ps)
}