lengthening channel inactivation?

[jamie]

I have cut and paste the .mod file below.

----------

Code: Select all

:   KV1.MOD
:
:   Kv1.2 channel model using HH-type activation/inactivation
:
:	mediuim spiny neurons
:
:   3/2003
:   Josh Held

NEURON {
	SUFFIX kv1_msn
	USEION k READ ek WRITE ik
	RANGE th, tm, ik, hinf, minf, g, gbar
    GLOBAL p
    GLOBAL vhm, vcm
    GLOBAL vhh, vch
    GLOBAL Cth, vhth, ath, bth, th0
    GLOBAL tm0, Ctm, vhtm, vctm
    GLOBAL th90
}

UNITS {
	(nS) = (millimho/cm2)
	(mV) = (millivolt)
	(mA) = (milliamp)
}

PARAMETER {
	gbar = 1 (millimho/cm2)
    ek (mV)
    vhm = -27 (mV)
    vhh = -33.477 (mV)
    vcm = -16 (mV)
    vch = 21.5 (mV)
    Cth = 548.67
    vhth = -0.956
    ath = 29.013
    bth= 100
    th0 = 779
    tm0 = 3.4
    Ctm = 89.2
    vhtm = -34.3
    vctm = 30.1
    p = 0.004
	celsius	(degC)
}

ASSIGNED {
	g (millimho/cm2)
	v (mV)
	minf
    hinf
	tm (ms)
    th (ms)
    th90 (ms)
	ik (mA/cm2)
}

STATE {
	m
    h
}

BREAKPOINT {
	SOLVE states METHOD cnexp
	g = gbar * (m^2) * h
	ik = g * (v - ek)
}

DERIVATIVE states{
	values()
	m' = (minf - m)/tm
    h' = (hinf - h)/th
}

INITIAL {
	values()
	m = minf
    h = hinf
}

PROCEDURE values() {LOCAL q10
	UNITSOFF
    q10 = 3^((celsius-22)/10)
    minf = 1/(1 + exp((v - vhm)/vcm))
    tm = (1/q10)*(tm0 + Ctm*exp(-((v-vhtm)/vctm)^2))

    hinf = (1-p)/(1 + exp((v - vhh)/vch)) + p
    th = (1/q10)*((Cth/(exp((v-vhth)/ath) + exp(-(v-vhth)/bth))) + th0)
    th90 = (1/q10)*((Cth/(exp((-90-vhth)/ath) + exp(-(-90-vhth)/bth))) + th0)
    UNITSON
}

----------

I would like the inactivation to take place on a longer time scale - that is I would like it to take longer to inactivate. But I don't know how to change the code to establish this.

Perhaps what would work would be to have some "fudge factor" (multiplicative factor perhaps) in the code equations that I can vary/play with to get the inactivation time I would like. But I don't know how to manipulate the code to get this. I guess the factor needs to be somewhere in the h inactivation system. Somewhere here perhaps:?

th = (1/q10)*((Cth/(exp((v-vhth)/ath) + exp(-(v-vhth)/bth))) + th0)

although I am far from sure.

thank you so, so much.

[ted]

Opportunities abound, and there is no need to tinker with the NMODL code.

The time constant for h is defined by
th = (1/q10)*((Cth/(exp((v-vhth)/ath) + exp(-(v-vhth)/bth))) + th0)
in PROCEDURE values(). The expression on the right hand side has a constant term,
which is proportional to th0, and a voltage-dependent term, which is proportional to Cth.
Both of those constants are declared as GLOBAL in the NEURON block, so both are
accessible at the hoc level (known as th0_kv1_msn and Cth_kv1_msn). All you have to
do is give new values to one or both of these, with simple assignment statements in hoc.