www.neuron.yale.edu

Code: Select all

COMMENT
"Pulse" synapse (you may think of this as a single ion channel
with fixed open time that responds to synaptic activation).
If the synapse is off, an input event increments g by g1 for duration dur.
If the synapse is on, input events have no effect.

Magnitude of the conductance is specified by PARAMETER g1,
not by the NetCon's weight.
ENDCOMMENT

NEURON {
  POINT_PROCESS PulseSyn
  RANGE dur, g1, e, g, i
  NONSPECIFIC_CURRENT i
}

UNITS {
  (nA) = (nanoamp)
  (mV) = (millivolt)
  (uS) = (microsiemens)
}

PARAMETER {
  dur = 0.1 (ms) <1e-9,1e9>
  g1 = 0 (uS) <0,1e9> : conductance response to a unitary event
  e = 0  (mV)
}

ASSIGNED {
  v (mV)
  i (nA)
  g (uS)
  on (1)
}

INITIAL {
  g = 0
  if (g1 < 0) { g1 = 0 }
  on = 0
}

BREAKPOINT {
  i = g*(v - e)
}

NET_RECEIVE(w) {
  : the only events that arrive when on==0 are input events
  if (on==0) {
    : a spike arrived and the channel is closed
    g = g1
    net_send(dur, 1) : to turn it off
    on = 1
  } else if (flag==1) {
    g = 0
    on = 0
  }
}