Specifying a finite volume of Extracellular fluid

[physrob]

Hi all

I am very new to Neuron, so apologies if I am asking a stupid question.

Does anyone know of a way to specify a finite volume of extracellular fluid?

Thanks

Rob

[ted]

You want a model of ion accumulation in extracellular space. Doable with NMODL, for example see the implementation of Frankenhaeuser-Hodgkin space in chapter 9 of The NEURON Book. For your convenience, I reproduce kext.mod here

Code: Select all

: Extracellular potassium ion accumulation
: fhspace and kxfer are from Frankenhaeuser & Hodgkin

NEURON {
  SUFFIX kext
  USEION k READ ik WRITE ko
  GLOBAL kbath
  RANGE fhspace, txfer
}

UNITS {
  (mV) = (millivolt)
  (mA) = (milliamp)
  FARADAY = (faraday) (coulombs)
  (molar) = (1/liter)
  (mM) = (millimolar)
}

PARAMETER {
  kbath = 2.5 (mM)
  : Frankenhaeuser-Hodgkin space parameters
  fhspace = 300 (angstrom) : thickness
  txfer = 50 (ms) : fhspace <-> bath transfer time
}

ASSIGNED {
  ik (mA/cm2)
}

STATE {
  ko (mM)
}

BREAKPOINT {
  SOLVE state METHOD derivimplicit
}

DERIVATIVE state {
  ko' = (1e8)*ik/(fhspace*FARADAY) + (kbath - ko)/txfer
}

An aside: astute readers may notice that the METHOD is now derivimplicit rather than cnexp. derivimplicit is appropriate for ion accumulation mechanisms specified by ODEs and will work regardless of the equilibration time constant.

[physrob]

Thanks Ted

I will have a good look at the relevant sections in the NEURON book.

Rob