I am working with 2 cell connected by an Expsyn. The first cell is 1 comp. (soma), the second cell is 2 comp (soma+dend).
I am using the na and k channels mechanisms by Migliore https://senselab.med.yale.edu/ModelDB/S ... mod#tabs-2 that should work fine at 35-37 degC.
I am using this intialization procedure:
Code: Select all
proc init() {
finitialize(v_init)
forall for (x,0) concentration_init()
forall for (x,0){
if (ismembrane("NaKpump")) {
ic_bias(x) = -(ina + ik + i_leakad +ink_NaKpump )
} else {
ic_bias(x) = -(ina+ik+i_leakad)
}
}
if (cvode.active()) {
cvode.re_init()
} else {
fcurrent()
}
frecord_init()
}
I had the same problem also using these simple models for na and k channel:
Code: Select all
:NMODL K+ current:
NEURON{
SUFFIX kad
USEION k READ ek WRITE ik
RANGE gkbar, ik
}
UNITS{
(S)=(siemens)
(mV)=(millivolt)
(mA)=(milliamp)
}
PARAMETER{gkbar=0.036 (S/cm2)}
ASSIGNED{
v (mV)
ek (mV) : typically ~ -70
ik (mA/cm2)
}
STATE{n}
BREAKPOINT{
SOLVE states METHOD cnexp
ik=gkbar*n^4*(v-ek)
}
INITIAL{
n=alpha(v)/(alpha(v)+beta(v))
}
DERIVATIVE states{
n'=(1-n)*alpha(v)-n*beta(v)
}
FUNCTION alpha(Vm (mV)) (/ms){
UNITSOFF
alpha=(0.01*((-70-Vm)+10))/(exp(((-70-Vm)+10)/10)-1)
UNITSON
}
FUNCTION beta(Vm (mV)) (/ms){
UNITSOFF
beta=0.125*exp((-70-Vm)/80)
UNITSON
}
:cambia 70 con 65
Code: Select all
:NMODL for Na+ current:
NEURON{
SUFFIX nad
USEION na READ ena WRITE ina
RANGE gnabar, ina
}
UNITS {
(S) = (siemens)
(mV) = (millivolt)
(mA) = (milliamp)
}
PARAMETER{ gnabar=0.12 (S/cm2)}
ASSIGNED{
v (mV)
ena (mV) : typically ~ +55
ina (mA/cm2)
}
STATE { m h}
BREAKPOINT{
SOLVE states METHOD cnexp
ina=gnabar*m^3*h*(v-ena)
}
INITIAL{
m=alpham(v)/(alpham(v)+betam(v))
h=alphah(v)/(alphah(v)+betah(v))
}
DERIVATIVE states{
m'=alpham(v)*(1-m)-m*betam(v)
h'=alphah(v)*(1-h)-betah(v)*h
}
FUNCTION alpham(Vm (mV)) (/ms){
UNITSOFF
alpham=(0.1*(-70-Vm+25))/(exp((-70-Vm+25)/10)-1)
UNITSON
}
FUNCTION betam(Vm (mV)) (/ms){
UNITSOFF
betam=4*exp((-70-Vm)/18)
UNITSON
}
FUNCTION alphah(Vm (mV)) (/ms){
UNITSOFF
alphah=0.07*exp((-70-Vm)/20)
UNITSON
}
FUNCTION betah(Vm (mV)) (/ms){
UNITSOFF
betah=1/(exp((-70-Vm+30)/10)+1)
UNITSON
}
Code: Select all
TITLE sodium potassium pump
: from Lindblad et al Am J Physiol 1996 275:H1666
NEURON {
SUFFIX NaKpump
USEION k READ ki, ko WRITE ik
USEION na READ nai, nao WRITE ina
RANGE ik, ina , INaKmax, ink, Kmko, Kmnai, n, m
GLOBAL dummy : prevent vectorization for use with CVODE
}
UNITS {
(mA) = (milliamp)
(mV) = (millivolt)
}
PARAMETER {
INaKmax = 2.18660e-3 (mA/cm2) <0,1e6>
Kmnai = 10 (mM) <0,1e6>
Kmko = 1.5 (mM) <0,1e6>
n=1.5
m=1
}
ASSIGNED {
celsius (degC)
v (mV)
ik (mA/cm2)
ina (mA/cm2)
ko (mM)
ki (mM)
nao (mM)
nai (mM)
ink (mA/cm2)
dummy
}
BREAKPOINT { LOCAL q10, fnk
fnk = (v + 150)/(v + 200)
ink= INaKmax*fnk/((1 + (Kmnai/nai)^n)*(1 + (Kmko/ko)^m))
ina = 3*ink
ik = -2*ink
}
Best
Menica